Создание нового WAV-файла

Delphi , Мультимедиа , Аудио

Данный документ был создан по многочисленным просьбам пользователей и описывает дополнительную функциональность компонента Delphi TMediaPlayer. Новая функциональность компонента заключается в возможности создания при записи нового файла формата .wav. Процедура "SaveMedia" создает тип record, передаваемый команде MCISend. Существует исключение, которое вызывает закрытие медиа при любой ошибке, возникающей при открытии определенного файла. Приложение состоит из двух кнопок. Button1 вызывает по-порядку процедуры OpenMedia и RecordMedia. Процедура CloseMedia вызывается при генерации приложением исключительной ситуации. Button2 вызывает процедуры StopMedia,SaveMedia и CloseMedia.

unit utestrec;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls,
  Forms, Dialogs, MPlayer, MMSystem, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure AppException(Sender: TObject; E: Exception);
  private
    FDeviceID: Word;
    { Private declarations }
  public
    procedure OpenMedia;
    procedure RecordMedia;
    procedure StopMedia;
    procedure SaveMedia;
    procedure CloseMedia;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

var
  MyError, Flags: Longint;

procedure TForm1.OpenMedia;
var
  MyOpenParms: TMCI_Open_Parms;
  MyPChar: PChar;
  TextLen: Longint;
begin
  Flags := mci_Wait or mci_Open_Element or mci_Open_Type;
  with MyOpenParms do
  begin
    dwCallback := Handle; // TForm1.Handle
    lpstrDeviceType := PChar('WaveAudio');
    lpstrElementName := PChar('');
  end;
  MyError := mciSendCommand(0, mci_Open, Flags,
    Longint(@MyOpenParms));
  if MyError = 0 then
    FDeviceID := MyOpenParms.wDeviceID;
end;

procedure TForm1.RecordMedia;
var
  MyRecordParms: TMCI_Record_Parms;
  TextLen: Longint;
begin
  Flags := mci_Notify;
  with MyRecordParms do
  begin
    dwCallback := Handle; // TForm1.Handle
    dwFrom := 0;
    dwTo := 10000;
  end;
  MyError := mciSendCommand(FDeviceID, mci_Record, Flags,
    Longint(@MyRecordParms));
end;

procedure TForm1.StopMedia;
var
  MyGenParms: TMCI_Generic_Parms;
begin
  if FDeviceID <> 0 then
  begin
    Flags := mci_Wait;
    MyGenParms.dwCallback := Handle; // TForm1.Handle
    MyError := mciSendCommand(FDeviceID, mci_Stop, Flags,
      Longint(@MyGenParms));
  end;
end;

procedure TForm1.SaveMedia;
type // не реализовано в Delphi
  PMCI_Save_Parms = ^TMCI_Save_Parms;
  TMCI_Save_Parms = record
    dwCallback: DWord;
    lpstrFileName: PAnsiChar; // имя файла, который нужно сохранить
  end;
var
  MySaveParms: TMCI_Save_Parms;
begin
  if FDeviceID <> 0 then
  begin
    // сохраняем файл...
    Flags := mci_Save_File or mci_Wait;
    with MySaveParms do
    begin
      dwCallback := Handle;
      lpstrFileName := PChar('c:\message.wav');
    end;
    MyError := mciSendCommand(FDeviceID, mci_Save, Flags,
      Longint(@MySaveParms));
  end;
end;

procedure TForm1.CloseMedia;
var
  MyGenParms: TMCI_Generic_Parms;
begin
  if FDeviceID <> 0 then
  begin
    Flags := 0;
    MyGenParms.dwCallback := Handle; // TForm1.Handle
    MyError := mciSendCommand(FDeviceID, mci_Close, Flags,
      Longint(@MyGenParms));
    if MyError = 0 then
      FDeviceID := 0;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  OpenMedia;
  RecordMedia;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  StopMedia;
  SaveMedia;
  CloseMedia;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.OnException := AppException;
end;

procedure TForm1.AppException(Sender: TObject; E: Exception);
begin
  CloseMedia;
end;

end.

Программный код на Delphi, который реализует компонент TMediaPlayer с дополнительными функциями для создания нового файла WAV при записи. Код состоит из двух кнопок, Button1 и Button2, которые используются для управления медиаплеером.

Кнопка Button1 отвечает за открытие устройства медиа (OpenMedia) и начало записи (RecordMedia).

Кнопка Button2 отвечает за остановку записи (StopMedia), сохранение записанных данных в файл WAV (SaveMedia) и закрытие устройства медиа (CloseMedia). Если при любом из этих операций возникает ошибка, программа закроет устройство медиа и будет завершена.

Вот подробное описание каждой процедуры:

1. OpenMedia: Открывает устройство медиа с помощью библиотеки MCI (Media Control Interface). Она настраивает callback-функцию для обработки событий от устройства медиа.
2. RecordMedia: Начинает запись аудиоданных с default звуковой карты. Записанные данные хранятся в буфере устройства медиа.
3. StopMedia: Останавливает процесс записи и освобождает буфер устройства медиа.
4. SaveMedia: Сохраняет записанные аудиоданные в файл WAV с помощью библиотеки MCI. Эта процедура создает новый тип записи (TMCI_Save_Parms) с полями для callback-функции, имени файла и других параметров. Затем она вызывает функцию mciSendCommand для сохранения аудиоданных в указанный файл.
5. CloseMedia: Закрывает устройство медиа, освобождая системные ресурсы.

Процедура AppException используется для обработки любых исключений, которые могут возникнуть при выполнении кода. Если исключение возникает, программа закроет устройство медиа и будет завершена.

Вот некоторые предложения по улучшению кода:

1. Обработка ошибок: Код можно улучшить добавлением более robust механизмов обработки ошибок. Например, вы можете использовать блоки try-except для ловли конкретных исключений и предоставления значимых сообщений об ошибках.
2. Организация кода: Код организован в отдельные процедуры для каждого операции медиа (открытие, запись, остановка, сохранение, закрытие). Это делает код более легко поддерживаемым и модифицируемым.
3. Документация: Код может получить дополнительную документацию и комментарии, чтобы объяснить его функциональность и использование.

Вот пример улучшения обработки ошибок:

procedure TForm1.SaveMedia;
var
  MySaveParms: TMCI_Save_Parms;
begin
  if FDeviceID <> 0 then
  begin
    try
      Flags := mci_Save_File or mci_Wait;
      with MySaveParms do
      begin
        dwCallback := Handle;
        lpstrFileName := PChar('c:\message.wav');
      end;
      MyError := mciSendCommand(FDeviceID, mci_Save, Flags, Longint(@MySaveParms));
    except
      on E: Exception do
      begin
         // Обрабатываем исключение и предоставляем сообщение об ошибке
        ShowMessage('Ошибка сохранения файла: ' + E.Message);
      end;
    end;
  end;
end;

В этом примере я добавил блок try-except для ловли любых исключений, которые могут возникнуть при операции сохранения. Исключение ловится и обрабатывается с помощью отображения сообщения об ошибке с помощью функции ShowMessage.

Данный документ описывает создание нового WAV-файла при помощи компонента Delphi TMediaPlayer, который позволяет записывать аудиосигнал в файл формата .wav.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Аудио ::