Программное сжатие размера файла базы Interbase

Delphi , Базы данных , Interbase

Автор: Savva
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> 
Предназначена для "сжатия" базы данных IB. Входные параметры: база данных,
имя и пароль к серверу IB. Возвращаемое значение: true - функция выполнилась
успешно, false - ошибка во время выполнения функции. Для работы использует
утилиту gbak.exe ииз поставки InterBase

Лирическое отступление.
Размер файла не сильно влияет на производительность, гораздо тяжелее
переносится не собранный мусор (база же постраничная). Interbase делает
сам сборку "мусора" (sweep),но после 20000 (по умолчанию) транзакций.
При этом файл базы не уменьшается. Что бы его уменьшить нужно сделать
резервную копию, а потом восстановить. Собственно это и делается в функции.

Зависимости: Forms (для курсора часиками), Registry, Windows, SysUtils, Dialogs
Автор: savva, savva@nm.ru, ICQ: 126578975, Орел
Copyright: Сапронов Алексей(Savva)
Дата: 13 июня 2002 г.
******************************************************}

function CompactInterBaseDatabase(DatabaseName, UserName, Password: string):
  boolean;
var
  tmpStr: array[0..MAX_PATH] of Char;
  TempPath: string; // путь
  ib_path: string; // путь сервера IB
  TempName: string; // имя временного файла
  bckName: string; //
  reg: TRegistry;
  si: STARTUPINFO;
  pi: PROCESS_INFORMATION;
  cmdline: string;
  SaveCursor: TCursor;
begin
  {
  используемые параметры командной строки
  -B(ACKUP_DATABASE) backup database to file
  -C(REATE_DATABASE) create database from backup file
  -PAS InterBase password
  -USER InterBase user name
  }
  result := false;
  SaveCursor := Screen.Cursor;
  Screen.Cursor := crHourGlass; // показываем часики
  try
    try // достаем размещение сервера IB
      Reg := TRegistry.Create;
      Reg.RootKey := HKEY_LOCAL_MACHINE;
      Reg.OpenKey('SOFTWARE\Borland\InterBase\CurrentVersion', False);
      ib_path := Reg.ReadString('ServerDirectory');
    finally
      Reg.Free;
    end;

    bckName := ChangeFileExt(ExtractFileName(DatabaseName), '.tmp');
    // получаем путь для временного файла
    TempPath := ExtractFilePath(DatabaseName);
    if TempPath = '' then
    begin
      TempPath := GetCurrentDir;
      DatabaseName := TempPath + '\' + DatabaseName;
    end;
    //получаем имя временного файла
    GetTempFileName(PChar(TempPath), 'gdb', 0, tmpStr);
    TempName := StrPas(tmpStr);
    // меняем ему расширение
    TempName := TempPath + '\' + ChangeFileExt(ExtractFileName(TempName),
      '.gdb');
    DeleteFile(PChar(TempName)); // этого файла не должно существовать :))

    ZeroMemory(@si, sizeof(si));
    si.cb := SizeOf(si);
    // прячем черное окошко. Если не надо прятать - то надо
    // просто убрать эти 2 строки
    si.dwFlags := STARTF_USESHOWWINDOW;
    si.wShowWindow := SW_HIDE;
    //-----------------------
    cmdline := ib_path + 'gbak.exe -b ' + DatabaseName + ' ' + TempName +
      ' -pas ' + Password + ' -user ' + UserName;
    if not CreateProcess(nil, // Используем командную строку.
      PChar(cmdline), // Командная строка.
      nil,
      nil, //
      False, //
      0, // флаги создания
      nil, // переменные окружения не меняем
      nil, // текущая директория не изменна
      si, // указатель на структуру STARTUPINFO .
      pi) {// указатель на структуру PROCESS_INFORMATION .} then
    begin
      raise ERangeError.CreateFmt(
        'Error in CompactInterBaseDatabase'#10#13'%s '  ,
        ['CreateProcess failed.']);
    end;
    WaitForSingleObject(pi.hProcess, INFINITE); // ждем бесконечно долго :)
    CloseHandle(pi.hProcess); // за собой надо
    CloseHandle(pi.hThread); // убирать
    RenameFile(DatabaseName, bckName);
    // переименовываем не упакованную базу - на всякий случай
    cmdline := ib_path + 'gbak.exe -c ' + TempName + ' ' + DatabaseName +
      ' -pas ' + Password + ' -user ' + UserName;
    if not CreateProcess(nil, // Используем командную строку.
      PChar(cmdline), // Командная строка.
      nil,
      nil, //
      False, //
      0, // флаги создания
      nil, // переменные окружения не меняем
      nil, // текущая директория не изменна
      si, // указатель на структуру STARTUPINFO .
      pi) {// указатель на структуру PROCESS_INFORMATION .} then
    begin
      raise ERangeError.CreateFmt(
        'Error in CompactInterBaseDatabase'#10#13'%s '  ,
        ['CreateProcess failed.']);
    end;
    WaitForSingleObject(pi.hProcess, INFINITE); // ждем бесконечно долго :)
    CloseHandle(pi.hProcess); // за собой надо
    CloseHandle(pi.hThread); // убирать

    DeleteFile(PChar(TempName)); // удаляем временный файл
    DeleteFile(PChar(bckName)); // удаляем не упакованную базу
    result := true; //все вроде вышло
  except // случилось страшное :)) Возвращаем все к прежнему виду
    on E: Exception do
    begin
      RenameFile(bckName, DatabaseName); // переименовываем не упакованную базу
      DeleteFile(PChar(TempName)); // удаляем временный файл
      result := false; // результат выполнения функции отрицателен
      // выдаем сообщение об исключительной ситуации
      ShowMessage(e.message);
    end;
  end;
  Screen.Cursor := SaveCursor; // возвращаем курсор на место
end;

Пример использования:

...
if CompactInterBaseDatabase('any_db.gdb', 'SYSDBA', 'masterkey') then
  ShowMessage('Done!');
...

Программа Delphi для сжатия файла базы данных Interbase с помощью утилиты gbak, предоставляемой Interbase. Программа принимает три параметра входа: имя файла базы данных, имя пользователя для сервера Interbase и пароль для сервера.

Вот шаги, которые выполняет программа:

1. Она извлекает путь к серверу Interbase из реестра Windows.
2. Создает временный файл-копию с расширением .tmp путем копирования оригинального файла базы данных.
3. Использует утилиту gbak для создания компактной версии файла базы данных, которая хранится в новом файле с расширением .gdb.
4. Программа ожидает завершения процесса gbak и затем переименовывает компактную версию файла базы данных, чтобы заменить оригинальный файл.
5. Если возникнут ошибки при процессе сжатия, программа откатит изменения и отобразит сообщение об ошибке.

Программа использует следующие зависимости:

• Forms (для отображения курсора)
• Registry
• Windows
• SysUtils
• Dialogs

Автор программы - Савва, она была выпущена в июне 2002 года.

Вот пример использования этой программы:

if CompactInterBaseDatabase('any_db.gdb', 'SYSDBA', 'masterkey') then
  ShowMessage('Done!');

Эта команда сжимает файл базы данных с именем any_db.gdb с использованием имени пользователя SYSDBA и пароля masterkey, а затем отображает сообщение об ошибке, если сжатие было успешным.

Программное сжатие размера файла базы Interbase - это функция, которая уменьшает размер файла базы данных Interbase, создавая временный файл и выполняя команду gbak.exe для упаковки неупакованного мусора в базе.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Interbase ::