Запись и чтение объекта TPersistent в поток

Delphi , Компоненты и Классы , Потоки

Автор: Mystic
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Запись/чтение объекта TPersistent в поток

Пара функций, выполняющих запись/чтение объекта,
порожденного от TPersistent, в поток.

ВНИМАНИЕ! Код этих процедур основан на VCL пятой версии Delphi.
Вполне возможно, что в последующих версиях Delphi он работать не будет!

Зависимости: Classes
Автор:       Mystic, mystic2000@newmail.ru, ICQ:125905046, Харьков
Copyright:   (c) Mystic
Дата:        25 января 2003 г.
***************************************************** }

unit PersistentIO;

interface

uses Classes;

procedure WritePersistent(S: TStream; Instance: TPersistent);
procedure ReadPersistent(S: TStream; Instance: TPersistent);

implementation

type
  TMyWriter = class(TWriter)
  public
    procedure WritePersistent(Instance: TPersistent);
  end;

procedure TMyWriter.WritePersistent(Instance: TPersistent);
begin
  WriteProperties(Instance);
  WriteListEnd;
end;

type
  TMyReader = class(TReader)
  public
    procedure ReadPersistent(Instance: TPersistent);
  end;

procedure TMyReader.ReadPersistent(Instance: TPersistent);
begin
  while not EndOfList do
    ReadProperty(Instance);
  ReadListEnd;
end;

procedure WritePersistent(S: TStream; Instance: TPersistent);
var
  Writer: TMyWriter;
begin
  Writer := TMyWriter.Create(S, 4096);
  try
    Writer.WritePersistent(Instance);
  finally
    Writer.Free;
  end;
end;

procedure ReadPersistent(S: TStream; Instance: TPersistent);
var
  Reader: TMyReader;
begin
  Reader := TMyReader.Create(S, 4096);
  try
    Reader.ReadPersistent(Instance);
  finally
    Reader.Free;
  end;
end;

end.

Код-снippet на языке Delphi, который предлагает два процедура для записи и чтения объекта типа TPersistent в/из поток (бинарный файл или буфер памяти).

Код состоит из следующих компонентов:

1. Два класса: TMyWriter и TMyReader, которые наследуются от TWriter и TReader, соответственно. Эти классы используются для записи и чтения объекта TPersistent в/из поток.
2. Две процедуры: WritePersistent и ReadPersistent, которые используют классы TMyWriter и TMyReader для выполнения операций записи и чтения.

Вот подробное описание, что каждая процедура делает:

WritePersistent

1. Создает экземпляр класса TMyWriter с потоком (S) и буфером размером 4096 байт.
2. Вызывает метод WriteProperties на объекте-писателе для записи всех свойств объекта TPersistent в поток.
3. Записывает маркер конца списка в поток с помощью WriteListEnd.
4. Наконец, освобождает объект-писатель.

ReadPersistent

1. Создает экземпляр класса TMyReader с потоком (S) и буфером размером 4096 байт.
2. Вызывает метод ReadProperty на объекте-читателе для чтения всех свойств объекта TPersistent из потока, пока не достигнет конца списка.
3. Читает маркер конца списка из потока с помощью ReadListEnd.
4. Наконец, освобождает объект-читатель.

Автор отмечает, что этот код специфичен для Delphi 5 и может не работать в более поздних версиях Delphi.

В целом, это код предлагает простой способ сериализации и десериализации объектов типа TPersistent, что может быть полезно для хранения и извлечения данных в бинарном формате.

Статья представляет собой пример кода на Delphi, который позволяет записывать и читать объекты TPersistent в поток с помощью классов TMyWriter и TMyReader.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Потоки ::