Вычисление определенного интеграла методом трапеций с заданной точностью

Delphi , Синтаксис , Математика

Автор: Romkin
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> 
Просто расчет площади под функцией, параметры: a,b - пределы интегрирования, a<=b
eps - допустимая погрешность, практически гарантируется, что расхождение результата
с истинным значением интеграла не превосходит по модулю указанную величину.
Только не переборщите :-))
intF - подинтегральная функция. Естественно, желательно задавать функции,
интегрируемые в смысле Римана. Объявление смотри в примере.
Примечание: Несобственные интегралы не считаем :-)
Проверок на переполнение нет, да и вообще нет проверок...

Зависимости: Ну какие могут быть зависимости?
Автор:       Romkin, romkin@pochtamt.ru, Москва
Copyright:   Romkin 2002
Дата:        19 ноября 2002 г.
***************************************************** }

unit intfunc;

interface

type
  TIntFunc = function(X: Double): Double;

function TrapezeInt(a, b: Double; eps: Double; IntF: TIntFunc): Double;

implementation

function TrapezeInt(a, b: Double; eps: Double; IntF: TIntFunc): Double;
var
  //S - площадь на предыдущей итерации,
  //x - текущее значение аргумента
  //base - высота трапеции
  //n - число трапеций, удваивается на каждой итерации
  S, x, base: Double;
  i, n: Integer;
begin
  //Сначала приближение одной трапецией
  base := b - a;
  Result := (IntF(a) + IntF(b)) / 2 * base;
  eps := eps / 10; //Вообще говоря, величина делителя зависит от функции
  n := 1;
  repeat
    S := Result;
    base := base / 2;
    n := n * 2;
    //Новая площадь вычисляется на основе старой
    Result := Result / 2;
    //Ниже - просто вычисляем площади новых трапеций
    for i := 1 to n div 2 do
    begin
      x := a + base * (i * 2 - 1);
      Result := Result + IntF(x) * base;
    end;
  until abs(S - Result) <= eps;
end;

end.

Пример использования:

uses intFunc;

function intSin(x: Double): Double;
begin
  Result := sin(x);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := FloatToStr(TrapezeInt(0, Pi, 0.00001, intSin));
  //результат у меня получился 1.99999990195429 - с запасом
  //Точный ответ - 2.0
end;

Привет! Я переведу текст на русский язык:

Это код Delphi, который рассчитывает определенный интеграл функции с помощью метода трапеций с указанной точностью. Функция TrapezeInt принимает четыре параметра: a и b - пределы интегрирования, eps - разрешенная ошибка, а IntF - функцию для интеграции.

Разбивка кода:

1. Секция интерфейса определяет тип TIntFunc для функции, которая принимает дробное значение и возвращает дробное значение.
2. Секция реализации содержит функцию TrapezeInt, которая рассчитывает интеграл с помощью метода трапеций.
3. Функция начинает с приблизительного расчета интеграла с помощью одиночной трапеции, а затем повторно уточняет приближение, делив интервал на две части и рассчитывая площадь каждой новой трапеции.
4. Переменная base представляет ширину каждой трапеции, которая удваивается в каждом шаге.
5. Переменная n отслеживает количество трапеций, использованных в текущей итерации, которое удваивается в каждом шаге.
6. Функция рассчитывает новое приближение, добавляя площади новых трапеций к предыдущему приближению и делив на 2.
7. Цикл продолжается, пока абсолютная разница между старым и новым приближениями не будет меньше или равна eps.

Пример использования функции TrapezeInt демонстрирует использование простой функции синуса (intSin).

Обратите внимание:

• Код не включает в себя обработку ошибок или проверки на недопустимые входные данные.
• Выбор начального значения для base и множителя в цикле итерации является произвольным и может повлиять на скорость сходимости алгоритма.
• Функция предполагает, что функция ввода IntF достаточно гладкая для интеграции с помощью метода трапеций.

В целом, этот код предоставляет основное реализацию метода трапеций для численной интеграли с указанной точностью.

В статье описана функция для вычисления определенного интеграла методом трапеций с заданной точностью, реализованная на языке Delphi.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Математика ::