Сканирование строки начиная с указанной позиции с целью нахождения слова

Delphi , Синтаксис , Текст и Строки

Автор: Алексей Вуколов
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Сканирование строки начиная с указанной позиции с целью нахождения слова.

Функция предназначена для разбиения строки на слова. Границы слов
определяются по разделителям.

Описание параметров:

S - строка, в которой производится поиск;

StartPos - на входе принимает позицию с которой начинается сканирование
строки, на выходе содержит позицию символа, с которого начинается слово;

WordLen - на выходе содержит длину найденного слова;

Delimiters - множество, содержащее символы-разделители слов;

Возвращаемое значение - true если слово найдено, инече false;

Зависимости: SysUtils
Автор:       vuk, vuk@fcenter.ru
Copyright:   Алексей Вуколов
Дата:        18 апреля 2002 г.
***************************************************** }

function WordScan(const S: string; var StartPos, WordLen: integer;
  Delimiters: TSysCharSet): boolean;
var
  i, l: integer;
begin
  Result := false;
  WordLen := 0;

  i := StartPos;
  l := length(s);
  StartPos := 0;
  while i <= l do
    if s[i] in Delimiters then
      inc(i)
    else
    begin
      StartPos := i;
      break;
    end;

  while i <= l do
    if not (s[i] in Delimiters) then
    begin
      inc(i);
      inc(WordLen);
    end
    else
      break;

  Result := WordLen <> 0;
end;

Пример использования:

//Консольная программа, выводящая на экран слова из заданной строки.

program Project1;
{$APPTYPE CONSOLE}
uses SysUtils;

var
  s: string;
  wStart, wLen: integer;
begin
  s := 'This is a test string. String contains delimiters.';
  wStart := 1;
  wLen := 0;
  while WordScan(s, wStart, wLen, [' ', '.', ',']) do
  begin
    writeln(copy(s, wStart, wLen));
    inc(wStart, wLen);
  end;
  readln;
end.

Функция WordScan в языке Delphi сканирует строку начиная с указанной позиции для поиска слова. Функция принимает четыре параметра:

• S: входная строка
• StartPos: начальная позиция сканирования (передается по ссылке)
• WordLen: длина найденного слова (передается по ссылке)
• Delimiters: набор символов, отделяющих слова

Функция возвращает булевое значение, указывающее, было ли найдено слово.

Разбивка кода:

1. Функция инициализирует переменную Result в false, что означает, что пока не было найдено слово.
2. Она устанавливает WordLen в 0, которое будет хранить длину найденного слова.
3. Функция затем проходит через входную строку начиная с указанной позиции (StartPos) до конца строки (l).
4. Внутри цикла если текущий символ находится в наборе разделителей, функция просто инкрементирует i для перехода к следующему символу. Если символ не является разделителем, функция устанавливает StartPos в текущую позицию и выходит из внутреннего цикла.
5. Внешний цикл продолжается с места, где он оставил, проверяя каждый последующий символ на принадлежность к набору разделителей. Если символ не является разделителем, функция инкрементирует длину слова (WordLen) и продолжает. Если она находит разделитель, функция выходит из цикла.
6. Наконец, функция устанавливает Result в true, если было найдено слово (т.е. WordLen больше 0).

Пример использования функции показывает, как использовать ее в консольном программе. Программа сканирует входную строку 'This is a test string. String contains delimiters.' и выводит каждый найденный символ.

Обратите внимание, что функция использует оператор in для проверки принадлежности символа к набору разделителей, что является удобным способом выполнения проверок на принадлежность в Delphi.

Функция WordScan позволяет сканировать строку с указанной позиции для нахождения слова, учитывая разделители и возвращая длину найденного слова.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Текст и Строки ::