Выставить значения свойств

Delphi , Компоненты и Классы , Свойства и События

Автор: Xavier Pacheco

unit MainFrm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

type
  TMainForm = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Panel1: TPanel;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Panel1Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;

implementation
uses TypInfo;
{$R *.DFM}

procedure SetIntegerPropertyIfExists(AComp: TComponent; APropName: string;
  AValue: Integer);
var
  PropInfo: PPropInfo;
begin
  PropInfo := GetPropInfo(AComp.ClassInfo, APropName);
  if PropInfo <> nil then
  begin
    if PropInfo^.PropType^.Kind = tkInteger then
      SetOrdProp(AComp, PropInfo, AValue);
  end;
end;

procedure SetObjectPropertyIfExists(AComponent: TComponent; APropName: string;
  AValue: TObject);
var
  PropInfo: PPropInfo;
begin
  PropInfo := GetPropInfo(AComponent.ClassInfo, APropName);
  if PropInfo <> nil then
  begin
    if PropInfo^.PropType^.Kind = tkClass then
      SetObjectProp(AComponent, PropInfo, AValue);
  end;
end;

procedure SetBooleanPropertyIfExists(AComp: TComponent; APropName: string;
  AValue: Boolean);
var
  PropInfo: PPropInfo;
begin
  PropInfo := GetPropInfo(AComp.ClassInfo, APropName);
  if PropInfo <> nil then
  begin
    if PropInfo^.PropType^.Kind = tkEnumeration then
      SetOrdProp(AComp, PropInfo, Integer(AValue));
  end;
end;

procedure SetStringPropertyIfExists(AComp: TComponent; APropName: string;
  AValue: string);
var
  PropInfo: PPropInfo;
  TK: TTypeKind;
begin
  PropInfo := GetPropInfo(AComp.ClassInfo, APropName);
  if PropInfo <> nil then
  begin
    TK := PropInfo^.PropType^.Kind;
    if (TK = tkString) or (TK = tkLString) or (TK = tkWString) then
      SetStrProp(AComp, PropInfo, AValue);
  end;
end;

procedure SetMethodPropertyIfExists(AComp: TComponent; APropName: string;
  AMethod: TMethod);
var
  PropInfo: PPropInfo;
begin
  PropInfo := GetPropInfo(AComp.ClassInfo, APropName);
  if PropInfo <> nil then
  begin
    if PropInfo^.PropType^.Kind = tkMethod then
      SetMethodProp(AComp, PropInfo, AMethod);
  end;
end;

procedure TMainForm.Button1Click(Sender: TObject);
begin
  SetStringPropertyIfExists(Button1, 'Caption', 'Yahoo');
end;

procedure TMainForm.Button2Click(Sender: TObject);
begin
  SetIntegerPropertyIfExists(Button2, 'Width', 50);
end;

procedure TMainForm.Button3Click(Sender: TObject);
begin
  SetBooleanPropertyIfExists(Button3, 'Enabled', False);
end;

procedure TMainForm.Button4Click(Sender: TObject);
var
  F: TFont;
begin
  F := TFont.Create;
  F.Name := 'Arial';
  F.Size := 24;
  F.Color := clRed;
  SetObjectPropertyIfExists(Panel1, 'Font', F);
end;

procedure TMainForm.Button5Click(Sender: TObject);
begin
  SetMethodPropertyIfExists(Button5, 'OnClick',
    GetMethodProp(Panel1, 'OnClick'));
end;

procedure TMainForm.Panel1Click(Sender: TObject);
begin
  ShowMessage(Button5.Caption);
end;

end.

Приведенный код - это проект Delphi, который устанавливает различные свойства компонентов в runtime с помощью процедур SetXXXXPropertyIfExists. Эти процедуры предназначены для установки свойств компонентов, если они существуют и имеют конкретный тип.

Вот подробное описание каждой процедуры:

1. SetIntegerPropertyIfExists: Устанавливает целочисленное свойство на компонент, если оно существует.
2. SetObjectPropertyIfExists: Устанавливает объектное свойство (например, шрифт) на компонент, если оно существует.
3. SetBooleanPropertyIfExists: Устанавливает булевое свойство на компонент, если оно существует.
4. SetStringPropertyIfExists: Устанавливает строковое свойство на компонент, если оно существует.
5. SetMethodPropertyIfExists: Устанавливает методное свойство на компонент, если оно существует.

В классе TMainForm эти процедуры используются для установки свойств различных компонентов при нажатии соответствующих кнопок:

1. Button1Click: Устанавливает заголовок кнопки Button1 в "Yahoo".
2. Button2Click: Устанавливает ширину кнопки Button2 в 50.
3. Button3Click: Отключает кнопку Button3.
4. Button4Click: Устанавливает шрифт панели Panel1 в custom-шрифт с конкретными свойствами.
5. Button5Click: Устанавливает обработчик события OnClick для кнопки Button5 в тот же, что и для панели Panel1.

Процедура Panel1Click - это обработчик события OnClick для панели Panel1. При этом событии она отображает сообщение с заголовком кнопки Button5.

Код демонстрирует, как динамически устанавливать свойства компонентов в runtime в Delphi. Однако стоит отметить, что использование этих процедур может сделать код более сложным и труднее для поддержки, особенно если есть много свойств для установки. Лучше использовать отдельные процедуры для каждого свойства или создавать более robust-систему для программной установки свойств.

В статье описывается использование процедур для установки значений свойств компонентов в Delphi, включая установку значений свойств типа integer, object, boolean и string.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Свойства и События ::