Перечислить измененные ключи реестра в определенный диапазон времени

Delphi , ОС и Железо , Реестр

Оформил: DeeCo
Автор: http://www.swissdelphicenter.ch

unit Main;

 interface

 uses
   Windows, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, Registry, StdCtrls, ComCtrls, ExtCtrls;

 type
   TFrmMain = class(TForm)
     Memo1: TMemo;
     btEnumReg: TButton;
     dtBeginDate: TDateTimePicker;
     dtEndDate: TDateTimePicker;
     dtBeginTime: TDateTimePicker;
     dtEndTime: TDateTimePicker;
     Panel1: TPanel;
     Label1: TLabel;
     Label2: TLabel;
     procedure btEnumRegClick(Sender: TObject);
   private
     { Private declarations }
     RegDate: TDateTime;
     RegKeyInfo: TRegKeyInfo;
     TimeZoneInfo: TTimeZoneInformation;
     function DateTimeToLocalDateTime(DateTime: TDateTime): TDateTime;
     procedure FileTimeToDateTime(ft: TFileTime; var dt: TDateTime);
   public
     { Public declarations }

   end;

 var
   FrmMain: TFrmMain;

 implementation

 {$R *.dfm}

 function TFrmMain.DateTimeToLocalDateTime(DateTime: TDateTime): TDateTime;
 begin
   case GetTimeZoneInformation(TimeZoneInfo) of
     TIME_ZONE_ID_STANDARD:
       Result := DateTime - (TimeZoneInfo.Bias / 60 / 24);
     TIME_ZONE_ID_DAYLIGHT:
       Result := DateTime - ((TimeZoneInfo.Bias + TimeZoneInfo.DaylightBias) / 60 / 24);
     else
       Result := 0;
   end;
 end;

 procedure TFrmMain.FileTimeToDateTime(ft: TFileTime; var dt: TDateTime);
 var
   SystemTime: TSystemTime;
   FileTime: TFileTime;
 begin
   if FileTimeToLocalFileTime(ft, FileTime) then
   begin
     FileTimeToSystemTime(ft, SystemTime);
     dt := SystemTimeToDateTime(SystemTime);
   end;
 end;

 procedure TFrmMain.btEnumRegClick(Sender: TObject);
 var
   Inizio, Fine: TDateTime;

   procedure EnumAllKeys(hkey: THandle; KeyName: string);
   var
     l: TStringList;
     n: Integer;
     KeyName_: string;
   begin
     KeyName_ := KeyName;
     with TRegistry.Create do
       try
         RootKey := hkey;
         OpenKey(EmptyStr, False);
         l := TStringList.Create;
         try
           GetKeynames(l);
           CloseKey;
           for n := 0 to l.Count - 1 do
           begin
             if OpenKey(l[n], False) then
             begin
               GetKeyInfo(RegKeyInfo);
               with RegKeyInfo do
               begin
                 FileTimeToDateTime(FileTime, RegDate);
                 RegDate := DateTimeToLocalDateTime(RegDate);
               end;
               if (RegDate <= Fine) and (RegDate >= Inizio) then
                 memo1.Lines.Add(DateTimeToStr(RegDate) + ' --- ' + KeyName_ + '\' + l[n]);
               EnumAllKeys(CurrentKey, KeyName_ + '\' + l[n]);
               CloseKey;
             end;
           end;
         finally
           l.Free
         end;
       finally
         Free;
       end;
   end;
 begin
   Memo1.Clear;
   Memo1.Lines.BeginUpdate;
   Inizio := int(dtBeginDate.DateTime) + frac(dtBeginTime.DateTime);
   Fine   := int(dtEndDate.Date) + frac(dtEndTime.DateTime);
   try
     EnumAllKeys(HKEY_CURRENT_USER, 'HKey_Current_User');
   finally
     Memo1.Lines.EndUpdate;
   end;

   MessageDlg('Enumeration ended', mtInformation, [mbOK], 0);
 end;

 end.

Программное приложение на Delphi, которое перечисляет измененные ключи в Windows-регистре в указанном временном диапазоне.

Оно выполняет следующие действия:

1. Форма имеет несколько дата/время-пикеров (dtBeginDate, dtEndDate, dtBeginTime и dtEndTime) для указания начала и конца временного диапазона.
2. Кнопка (btEnumReg) используется для запуска процесса перечисления.
3. Когда кнопка нажата, приложение очищает поле мемо (Memo1).
4. Затем оно задает два переменные, Inizio (начало даты) и Fine (конец даты), используя значения из дата/время-пикеров.
5. Приложение использует рекурсивную функцию EnumAllKeys, чтобы перечислить все ключи в регистре в указанном временном диапазоне. Функция принимает handle (hkey) и имя ключа как параметры.
6. Внутри функции EnumAllKeys оно перебирает каждый подключ и проверяет, если дата последней модификации падает в указанный временной диапазон. Если это так, оно добавляет имя ключа и дату последней модификации в поле мемо (Memo1).
7. Приложение затем отображает сообщательное окно с успешным сообщением после завершения перечисления.

Код использует несколько функций Windows API, таких как GetKeynames, GetKeyInfo, FileTimeToDateTime и SystemTimeToDateTime, чтобы взаимодействовать с регистром и конвертировать файловые времена в даты.

Вот предложенная альтернативная решение:

Вместо использования рекурсивных функций вызовов, можно использовать подход на основе стека для перечисления ключей. Это будет более эффективно и менее уязвимо для переполнения стека при работе с более крупными регистрами.

Кроме того, вам может быть полезно добавить обработку ошибок для случаев, когда операции с регистром неудачны или временной диапазон недействителен.

Перечислить измененные ключи реестра в определенный диапазон времени: программа на Delphi для отображения истории изменений в реестре Windows с указанием даты и времени изменения.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Реестр ::