Самолет летит по небу

Delphi , Графика и Игры , Canvas

unit aplane_;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Timer1: TTimer;
    Image1: TImage;
    procedure FormActivate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}
var
  Back, bitmap, Buf: TBitMap; // фон, картинка, буфер
  BackRct: TRect; // область фона, которая должна быть
  // восстановлена из буфера
  BufRct: Trect; // область буфера, которая используется для
  // восстановления фона

  x, y: integer; // текущее положение картинки
  W, H: integer; // размеры картинки

procedure TForm1.FormActivate(Sender: TObject);
begin
  // создать три объекта - битовых образа
  Back := TBitmap.Create; // фон
  bitmap := TBitmap.Create; // картинка
  Buf := TBitmap.Create; // буфер

  // загрузить и вывести фон
  Back.LoadFromFile('factory.bmp');
  Form1.Image1.canvas.Draw(0, 0, Back);

  // загрузить картинку, которая будет двигаться
  bitmap.LoadFromFile('aplane.bmp');
  // определим "прозрачный" цвет
  bitmap.Transparent := True;
  bitmap.TransParentColor := bitmap.canvas.pixels[1, 1];

  // создать буфер для сохранения копии области фона,
  // на которую накладывается картинка
  W := bitmap.Width;
  H := bitmap.Height;
  Buf.Width := W;
  Buf.Height := H;
  Buf.Palette := Back.Palette; // Чтобы обеспечить соответствие палитр !!
  Buf.Canvas.CopyMode := cmSrcCopy;
  // определим область буфера, которая будет использоваться
  // для восстановления фона
  BufRct := Bounds(0, 0, W, H);

  // начальное положение картинки
  x := -W;
  y := 20;

  // определим сохраняемую область фона
  BackRct := Bounds(x, y, W, H);
  // и сохраним ее
  Buf.Canvas.CopyRect(BufRct, Back.Canvas, BackRct);
end;

// обработка сигнала таймера

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  // восстановлением фона (из буфера) удалим рисунок
  Form1.image1.canvas.Draw(x, y, Buf);

  x := x + 2;
  if x > form1.Image1.Width then
    x := -W;

  // определим сохраняемую область фона
  BackRct := Bounds(x, y, W, H);
  // сохраним ее копию
  Buf.Canvas.CopyRect(BufRct, Back.Canvas, BackRct);

  // выведем рисунок
  Form1.image1.canvas.Draw(x, y, bitmap);
end;

// завершение работы программы

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  // освободим память, выделенную
  // для хранения битовых образов
  Back.Free;
  bitmap.Free;
  Buf.Free;
end;

end.

Программа на Delphi, которая создает анимированный самолет, который летит по фону формы. Вот разбивка кода:

Form1: Основная форма приложения, содержащая контрол изображения (Image1) и таймер (Timer1).

Переменные:

• Back: Объект TBitmap, используемый для хранения фоновой картинки.
• bitmap: Объект TBitmap, используемый для хранения изображения самолета.
• Buf: Объект TBitmap, используемый как буфер для хранения фоновой картинки.
• x и y: Целочисленные переменные, используемые для отслеживания позиции самолета.
• W и H: Целочисленные переменные, используемые для хранения ширины и высоты изображения самолета.

Процедура FormActivate: Провоцируется при активации формы. Она загружает фоновую картинку (Back) из файла, настраивает изображение самолета (bitmap) с прозрачным цветом, создает буфер (Buf) для хранения фоновой картинки и инициализирует позицию самолета (x и y).

Процедура Timer1Timer: Провоцируется каждый раз, когда таймер тикает (каждые 50 миллисекунд в этом случае). Она:

• Восстанавливает фоновую картинку из буфера (Buf) в контрол изображения (Image1).
• Обновляет позицию самолета, перемещая его вправо.
• Если самолет достиг конца формы, он сбрасывает свою позицию обратно слева.
• Сохраняет копию обновленной фоновой картинки в буфер.

Процедура FormClose: Провоцируется при закрытии формы. Она освобождает память, выделенную для объектов bitmap (Back, bitmap и Buf).

В целом, этот код создает анимированный эффект, перемещая самолет по фоновой картинке, которая хранится в буфере для предотвращения перерисовки всей картинки каждый раз.

Как создать программу на Delphi, которая рисует самолет, движущийся по фону.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Canvas ::