Проверка наличия .NET Framework и определение его версии

Delphi , ОС и Железо , Windows

Автор: Dimka Maslov
WEB-сайт: http://delphibase.endimus.com

{ **** UBPFD *********** by delphibase.endimus.com ****
>> 
Функция возвращает номер последней установленной версии .NET Framework
на компьютере, или пустую строку, если платформа .NET не установлена,
либо установлена криво.

Зависимости: Registry, SysUtils
Автор:       Dimka Maslov, mainbox@endimus.com, ICQ:148442121, Санкт-Петербург
Copyright:   Dimka Maslov
Дата:        19 января 2004 г.
***************************************************** }

function DotNetVersion: string;
var
  R: TRegistry;
  L: TStringList;
  S: string;
  i, MaxIndex, N, Code: Integer;
  V, MaxVersion: Double;
const
  RegKey = 'Software\Microsoft\.NETFramework\Policy';
begin
  Result := '';
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_LOCAL_MACHINE;
    if R.KeyExists(RegKey) then
    begin
      R.OpenKeyReadOnly(RegKey);
      L := TStringList.Create;
      try
        R.GetKeyNames(L);
        MaxVersion := -1.0;
        MaxIndex := -1;
        for i := 0 to L.Count - 1 do
        begin
          S := L[i];
          if UpCase(S[1]) = 'V' then
          begin
            Delete(S, 1, 1);
            Val(S, V, Code);
            if (Code = 0) and (V > MaxVersion) then
            begin
              MaxVersion := V;
              MaxIndex := i;
            end;
          end;
        end;
        if MaxIndex <> -1 then
        begin
          S := L[MaxIndex];
          R.CloseKey;
          R.OpenKeyReadOnly(RegKey + '\' + S);
          R.GetValueNames(L);
          MaxIndex := -1;
          for i := 0 to L.Count - 1 do
          begin
            Val(L[i], N, Code);
            if (Code = 0) and (N > MaxIndex) then
              MaxIndex := N;
          end;
          Result := S;
          Delete(Result, 1, 1);
          if MaxIndex <> -1 then
            Result := Result + '.' + IntToStr(MaxIndex);
        end;
      finally
        L.Free;
      end;
    end;
  finally
    R.Free;
  end;
end;

Программная функция DotNetVersion в языке программирования Delphi, которая проверяет, установлен ли на компьютере .NET Framework, и возвращает его версию в виде строки.

Функция выполняет следующие шаги:

1. Создает объект TRegistry (R) для доступа к реестру Windows.
2. Открывает ключ реестра 'Software\Microsoft.NETFramework\Policy' в режиме только для чтения.
3. Если ключ существует, функция проходит по всем подключам под этого ключа и проверяет, начинаются ли они с 'V'. Если да, она извлекает номер версии из имени подключа (например, 'v2.0.50727') и хранит его в объекте TStringList (L).
4. Функция находит максимальную версию среди всех извлеченных версий и хранит соответствующий ключ (S) в переменной.
5. Если найдена максимальная версия, функция открывает подключ, соответствующий этой версии, и получает имена значений (например, 'ServicePack', 'Release', и т.д.) в другой объект TStringList (L).
6. Функция извлекает номер релиза из этих имен значений и хранит его в переменной.
7. Наконец, функция возвращает строку версии как конкатенацию major-версии и номера релиза (например, '2.0.50727').

Функция использует несколько переменных для хранения промежуточных результатов:

• S: Имя ключа максимальной версии.
• L: Объект TStringList, используемый для хранения извлеченных версий и имен значений.
• V: Номер версии в виде дробного значения.
• Code: Целочисленное код ошибки, возвращаемое функцией Val.
• MaxIndex: Целочисленная переменная, хранящая индекс максимальной версии.
• N: Целочисленная переменная, используемая для извлечения номера релиза из значений подключов.

Функция возвращает пустую строку ('') если .NET Framework не установлен или установлен неправильно. В противном случае она возвращает строку версии как конкатенацию major-версии и номера релиза.

Функция DotNetVersion возвращает номер последней установленной версии .NET Framework на компьютере, или пустую строку, если платформа .NET не установлена или установлена криво.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Windows ::