Работа с именем компонента

unit NameF;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    ButtonUpdate: TButton;
    Label1: TLabel;
    ButtonGetName: TButton;
    Label2: TLabel;
    EditName: TEdit;
    ButtonChange: TButton;
    ButtonWeird: TButton;
    EditNewName: TEdit;
    Label3: TLabel;
    ButtonGetField: TButton;
    procedure ButtonUpdateClick(Sender: TObject);
    procedure ButtonChangeClick(Sender: TObject);
    procedure ButtonGetNameClick(Sender: TObject);
    procedure ButtonGetFieldClick(Sender: TObject);
    procedure ButtonWeirdClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.ButtonUpdateClick(Sender: TObject);
var
  I: Integer;
begin
  ListBox1.Items.Clear;
  for I := 0 to ComponentCount - 1 do
    ListBox1.Items.Add (Components [I].Name);
end;

procedure TForm1.ButtonChangeClick(Sender: TObject);
begin
  if Assigned (ButtonChange) then
    ButtonChange.Name := EditNewName.Text
  else
    Beep;
end;

procedure TForm1.ButtonGetNameClick(Sender: TObject);
begin
  if FindComponent (EditName.Text) <> nil then
    ShowMessage (EditName.Text + ' component exists')
  else
    ShowMessage (EditName.Text +
      ' component doesn''t exist');
end;

procedure TForm1.ButtonGetFieldClick(Sender: TObject);
var
  Field: ^TComponent;
begin
  Field := FieldAddress (EditName.Text);
  if Field <> nil then
  begin
    if Field^ = nil then
      ShowMessage (EditName.Text +
        ' field found, but not connected with a component')
    else
      ShowMessage (EditName.Text + ' field found');
  end;
end;

procedure TForm1.ButtonWeirdClick(Sender: TObject);
var
  Temp: TComponent;
begin
  // exchange the names
  Temp := ButtonUpdate;
  ButtonUpdate.Name := 'Temp999';
  ButtonWeird.Name := 'ButtonUpdate';
  Temp.Name := 'ButtonWeird';
  // which button is disabled/moved?
  ButtonUpdate.Enabled := False;
  ButtonWeird.Left := ButtonWeird.Left + 5;
end;

end.