Иконка на TrayBar - пример 2

Delphi , Рабочий стол , TrayBar

unit shellUnit;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Menus;

const
  WM_MYICONNOTIFY = WM_USER + 123;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    RestoreItem: TMenuItem;
    N1: TMenuItem;
    FileExitItem1: TMenuItem;
    HideItem: TMenuItem;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure RestoreItemClick(Sender: TObject);
    procedure HideItemClick(Sender: TObject);
    procedure FileExitItem1Click(Sender: TObject);
  private
    { Private declarations }
    ShownOnce: Boolean;
  public
    { Public declarations }
    procedure WMICON(var msg: TMessage); message WM_MYICONNOTIFY;
    procedure WMSYSCOMMAND(var msg: TMessage); message WM_SYSCOMMAND;
    procedure RestoreMainForm;
    procedure HideMainForm;
    procedure CreateTrayIcon(n: Integer);
    procedure DeleteTrayIcon(n: Integer);
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}
uses ComObj, activex, ShellApi, shlobj, registry;

procedure TForm1.WMICON(var msg: TMessage);
var P: TPoint;
begin
  case msg.LParam of
    WM_LBUTTONDOWN:
      begin
        GetCursorPos(p);
        SetForegroundWindow(Application.MainForm.Handle);
        PopupMenu1.Popup(P.X, P.Y);
      end;
    WM_LBUTTONDBLCLK: RestoreItemClick(Self);
  end;
end;

procedure TForm1.WMSYSCOMMAND(var msg: TMessage);
begin
  inherited;
  if (Msg.wParam = SC_MINIMIZE) then HideItemClick(Self);
end;


procedure TForm1.HideMainForm;
begin
  Application.ShowMainForm := False;
  ShowWindow(Application.Handle, SW_HIDE);
  ShowWindow(Application.MainForm.Handle, SW_HIDE);
end;

procedure TForm1.RestoreMainForm;
var i, j: Integer;
begin
  Application.ShowMainForm := True;
  ShowWindow(Application.Handle, SW_RESTORE);
  ShowWindow(Application.MainForm.Handle, SW_RESTORE);
  if not ShownOnce then
  begin
    for I := 0 to Application.MainForm.ComponentCount - 1 do
      if Application.MainForm.Components[I] is TWinControl then
        with Application.MainForm.Components[I] as TWinControl do
          if Visible then
          begin
            ShowWindow(Handle, SW_SHOWDEFAULT);
            for J := 0 to ComponentCount - 1 do
              if Components[J] is TWinControl then
                ShowWindow((Components[J] as TWinControl).Handle, SW_SHOWDEFAULT);
          end;
    ShownOnce := True;
  end;

end;

procedure TForm1.CreateTrayIcon(n: Integer);
var nidata: TNotifyIconData;
begin
  with nidata do
  begin
    cbSize := SizeOf(TNotifyIconData);
    Wnd := Self.Handle;
    uID := 1;
    uFlags := NIF_ICON or NIF_MESSAGE or NIF_TIP;
    uCallBackMessage := WM_MYICONNOTIFY;
    hIcon := Application.Icon.Handle;
    StrPCopy(szTip, Application.Title);
  end;
  Shell_NotifyIcon(NIM_ADD, @nidata);
end;

procedure TForm1.DeleteTrayIcon(n: Integer);
var nidata: TNotifyIconData;
begin
  with nidata do
  begin
    cbSize := SizeOf(TNotifyIconData);
    Wnd := Self.Handle;
    uID := 1;
  end;
  Shell_NotifyIcon(NIM_DELETE, @nidata);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ShownOnce := False;
  CreateTrayIcon(1);
  HideItem.Enabled := False;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeleteTrayIcon(1);
end;

procedure TForm1.RestoreItemClick(Sender: TObject);
begin
  RestoreMainForm;
  DeleteTrayIcon(1);
  RestoreItem.Enabled := False;
  HideItem.Enabled := True;
end;

procedure TForm1.HideItemClick(Sender: TObject);
begin
  HideMainForm;
  CreateTrayIcon(1);
  HideItem.Enabled := False;
  RestoreItem.Enabled := True;
end;

procedure TForm1.FileExitItem1Click(Sender: TObject);
begin
  Close;
end;

end.

Это проект Delphi, который демонстрирует создание системного иконки в области уведомлений и реализацию основной функциональности для нее, включая скрытие и восстановление основной формы.

Вот разбивка кода:

1. Класс TForm1 представляет собой основную форму приложения.
2. Процедура WMICON обрабатывает уведомительное сообщение, отправленное системной иконкой в области уведомлений при получении события нажатия левой кнопки мыши или двойного клика.
3. Процедура WMSYSCOMMAND обрабатывает сообщение WM_SYSCOMMAND, которое отправляется, когда пользователь минимизирует основную форму. В этом случае программа скрывает основную форму.
4. Процедуры CreateTrayIcon и DeleteTrayIcon создают и удаляют системную иконку в области уведомлений соответственно.
5. Процедуры HideMainForm и RestoreMainForm скрывают и восстанавливают основную форму соответственно.
6. Процедура FormCreate создает системную иконку в области уведомлений при создании основной формы.
7. Процедура FormDestroy удаляет системную иконку в области уведомлений при уничтожении основной формы.
8. Процедуры RestoreItemClick и HideItemClick обрабатывают события клика для пунктов меню "Восстановить" и "Скрыть" соответственно.
9. Процедура FileExitItem1Click обрабатывает событие клика для пункта меню "Выход".

Системная иконка в области уведомлений может быть настроена изменением иконки и текста подсказки в записи TNotifyIconData.

Обратите внимание, что этот код использует функцию Shell_NotifyIcon Windows API для создания и удаления системной иконки в области уведомлений. Запись TNotifyIconData используется для указания свойств системной иконки в области уведомлений, таких как ее размер,.handle и callback-сообщение.

Этот проект демонстрирует основную функциональность для системной иконки в области уведомлений и может быть расширен для включения дополнительных функций и возможностей.

В статье описывается создание иконки на панели задач (TrayBar) в Delphi, а также управление ей при помощи popup-меню.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: TrayBar ::