Карта сайта Kansoftware
НОВОСТИУСЛУГИРЕШЕНИЯКОНТАКТЫ
Разработка программного обеспечения
KANSoftWare

Освобождение памяти

Delphi , Синтаксис , Память и Указатели

Освобождение памяти

unit MemMan;

interface

var
  GetMemCount, FreeMemCount,
    ReallocMemCount: Integer;

implementation

uses
  Windows, SysUtils;

var
  OldMemMgr: TMemoryManager;

function NewGetMem(Size: Integer): Pointer;
begin
  Inc(GetMemCount);
  Result := OldMemMgr.GetMem(Size);
end;

function NewFreeMem(P: Pointer): Integer;
begin
  Inc(FreeMemCount);
  Result := OldMemMgr.FreeMem(P);
end;

function NewReallocMem(P: Pointer; Size: Integer): Pointer;
begin
  Inc(ReallocMemCount);
  Result := OldMemMgr.ReallocMem(P, Size);
end;

const
  NewMemMgr: TMemoryManager = (
    GetMem: NewGetMem;
    FreeMem: NewFreeMem;
    ReallocMem: NewReallocMem);

initialization
  GetMemoryManager(OldMemMgr);
  SetMemoryManager(NewMemMgr);

finalization
  SetMemoryManager(OldMemMgr);
  if (GetMemCount - FreeMemCount) <> 0 then
    MessageBox(0, pChar(
      'Objects left: ' + IntToStr(GetMemCount - FreeMemCount)),
      'MemManager', mb_ok);
end.
unit MemForm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    BtnRefresh1: TButton;
    BtnCreateNil: TButton;
    BtnCreateOwner: TButton;
    BtnGetMem: TButton;
    LblResult: TLabel;
    Btn100Strings: TButton;
    Bevel1: TBevel;
    BtnRefresh2: TButton;
    procedure BtnRefresh1Click(Sender: TObject);
    procedure BtnCreateNilClick(Sender: TObject);
    procedure BtnCreateOwnerClick(Sender: TObject);
    procedure BtnGetMemClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Btn100StringsClick(Sender: TObject);
    procedure BtnRefresh2Click(Sender: TObject);
  public
    procedure Refresh;
    procedure Refresh2;
  end;

var
  Form1: TForm1;

implementation

uses MemMan;

{$R *.DFM}

procedure TForm1.Refresh;
begin
  LblResult.Caption :=
    'Allocated: ' + IntToStr(GetMemCount) + #13 +
    'Free: ' + IntToStr(FreeMemCount) + #13 +
    'Existing: ' +
    IntToStr(GetMemCount - FreeMemCount) + #13 +
    'Re-allocated: ' + IntToStr(ReallocMemCount);
end;

procedure TForm1.Refresh2;
begin
  LblResult.Caption := Format(
    'Allocated: %d'#13'Free: %d'#13'Existing: %d'#13'Re-allocated %d'      ,
    [GetMemCount, FreeMemCount,
    GetMemCount - FreeMemCount, ReallocMemCount]);
end;

procedure TForm1.BtnRefresh1Click(Sender: TObject);
begin
  Refresh;
end;

procedure TForm1.BtnCreateNilClick(Sender: TObject);
begin
  TButton.Create(nil);
  Refresh;
end;

procedure TForm1.BtnCreateOwnerClick(Sender: TObject);
begin
  TButton.Create(self);
  Refresh;
end;

procedure TForm1.BtnGetMemClick(Sender: TObject);
var
  P: Pointer;
begin
  GetMem(P, 100);
  Integer(P^) := 0;
  Refresh;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Refresh;
end;

procedure TForm1.Btn100StringsClick(Sender: TObject);
var
  s1, s2: string;
  I: Integer;
begin
  s1 := 'hi';
  s2 := Btn100Strings.Caption;
  for I := 1 to 100 do
    s1 := s1 + ': hello world';
  Btn100Strings.Caption := s1;
  s1 := s2;
  Btn100Strings.Caption := s1;
  Refresh;
end;

procedure TForm1.BtnRefresh2Click(Sender: TObject);
begin
  Refresh2;
end;

end.
Скачать весь проект

Это проект на языке Delphi, демонстрирующий управление памятью с помощью кастомного менеджера памяти, который отслеживает количество выделенных, освобожденных и реаллокированных памяти.

Unit MemMan В этом модуле определены три функции: NewGetMem, NewFreeMem и NewReallocMem. Они используются для отслеживания количества выделенной, освобожденной и реаллокированной памяти.

В секции инициализации модуль получает текущий менеджер памяти и сохраняет его в переменной OldMemMgr. Затем он устанавливает кастомный менеджер памяти (NewMemMgr) как новый дефолтный менеджер памяти с помощью функции SetMemoryManager.

В секции финализации модуль восстанавливает оригинальный менеджер памяти (OldMemMgr) и проверяет, есть ли какие-либо объекты, которые не были освобождены (то есть, не были освобождены), и отображает сообщение с количеством таких объектов.

Unit MemForm В этом модуле определена форма с несколькими кнопками, демонстрирующими различные сценарии управления памятью. Форма имеет три процедуры: Refresh, Refresh2 и несколько обработчиков кликов кнопок.

  • Процедура Refresh обновляет метку формы, отображая текущее состояние выделенной, освобожденной и реаллокированной памяти.
  • Процедура Refresh2 аналогична процедуре Refresh, но использует форматированную строку вместо конкатенации строк с помощью оператора +.
  • Обработчики кликов кнопок:
    • BtnCreateNilClick: Создает новую кнопку с nil как ее владельцем (то есть, не является владельцем формы).
    • BtnCreateOwnerClick: Создает новую кнопку с self (формой) как ее владельцем.
    • BtnGetMemClick: Выделяет 100 байт памяти и присваивает их целочисленной переменной.
    • Btn100StringsClick: Создает строку с 100 копиями "hi: hello world" и обновляет текст кнопки.
    • BtnRefresh1Click и BtnRefresh2Click: Вызывают соответствующие процедуры Refresh.
  • Форма также имеет несколько переменных, включая GetMemCount, FreeMemCount и ReallocMemCount, которые используются для отслеживания количества выделенной, освобожденной и реаллокированной памяти. Процедура FormCreate вызывается при создании формы и инициализирует эти переменные.
  • В целом, этот проект демонстрирует, как создавать кастомный менеджер памяти и использовать его для отслеживания управления памятью в приложениях Delphi.

Освобождение памяти в приложении Delphi с использованием класса TMemoryManager и его переопределением для отслеживания аллокированных, освобожденных и реаллокированных ресурсов.


Комментарии и вопросы


Ваше мнение или вопрос к статье в виде простого текста (Tag <a href=... Disabled). Все комментарии модерируются, модератор оставляет за собой право удалить непонравившейся ему комментарий.

заголовок

e-mail

Ваше имя

Сообщение

Введите код




Материалы статей собраны из открытых источников, владелец сайта не претендует на авторство. Там где авторство установить не удалось, материал подаётся без имени автора. В случае если Вы считаете, что Ваши права нарушены, пожалуйста, свяжитесь с владельцем сайта.



:: Главная :: Память и Указатели ::


реклама



©KANSoftWare (разработка программного обеспечения, создание программ, создание интерактивных сайтов), 2007
Top.Mail.Ru

Время компиляции файла: 2024-06-02 10:20:12
2024-06-16 02:44:01/0.0072319507598877/2