Расширенные сведения о памяти

Delphi , Синтаксис , Память и Указатели

unit MemForm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Grids, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Timer1: TTimer;
    StringGrid2: TStringGrid;
    BtnString: TButton;
    BtnStringList: TButton;
    BtnForm: TButton;
    BtnBigAlloc: TButton;
    BtnSmallAlloc: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure BtnStringClick(Sender: TObject);
    procedure BtnStringListClick(Sender: TObject);
    procedure BtnFormClick(Sender: TObject);
    procedure BtnSmallAllocClick(Sender: TObject);
    procedure BtnBigAllocClick(Sender: TObject);
  private
    procedure UpdateStatus;
  public
    s: string;
    sl: TStringList;
    f: TForm;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.UpdateStatus;
var
  MemStatus: TMemoryStatus;
  HeapStatus: THeapStatus;
begin
  MemStatus.dwLength := sizeof(TMemoryStatus);
  GlobalMemoryStatus(MemStatus);
  with MemStatus do
  begin
    // load
    StringGrid1.Cells[1, 0] := IntToStr(dwMemoryLoad) + '%';

    // RAM (total, free, load)
    StringGrid1.Cells[1, 1] := FloatToStrF(
      dwTotalPhys / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 2] := FloatToStrF(
      dwAvailPhys / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 3] := IntToStr(100 -
      dwAvailPhys div (dwTotalPhys div 100)) + '%';

    // page file (total, free, load)
    StringGrid1.Cells[1, 4] := FloatToStrF(
      dwTotalPageFile / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 5] := FloatToStrF(
      dwAvailPageFile / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 6] := IntToStr(100 -
      dwAvailPageFile div (dwTotalPageFile div 100)) + '%';

    // page file (total, used, free)
    StringGrid1.Cells[1, 7] := FloatToStrF(
      dwTotalVirtual / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 8] := FloatToStrF(
      dwAvailVirtual / 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid1.Cells[1, 9] := FloatToStrF(
      (dwTotalVirtual - dwAvailVirtual) / 1024,
      ffNumber, 20, 0) + ' Kbytes';
  end; // with MemStatus

  HeapStatus := GetHeapStatus;
  with HeapStatus do
  begin
    StringGrid2.Cells[1, 0] := FloatToStrF(
      TotalAddrSpace div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 1] := FloatToStrF(
      TotalUncommitted div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 2] := FloatToStrF(
      TotalCommitted div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 3] := FloatToStrF(
      TotalFree div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 4] := FloatToStrF(
      TotalAllocated div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 5] := IntToStr(
      TotalAllocated div (TotalAddrSpace div 100)) + '%';
    StringGrid2.Cells[1, 6] := FloatToStrF(
      FreeSmall div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 7] := FloatToStrF(
      FreeBig div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 8] := FloatToStrF(
      Unused div 1024,
      ffNumber, 20, 0) + ' Kbytes';
    StringGrid2.Cells[1, 9] := FloatToStrF(
      Overhead div 1024,
      ffNumber, 20, 0) + ' Kbytes';
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  StringGrid1.Cells[0, 0] := 'Memory load';
  StringGrid1.Cells[0, 1] := 'Physical memory';
  StringGrid1.Cells[0, 2] := 'Free physical memory';
  StringGrid1.Cells[0, 3] := 'RAM load';
  StringGrid1.Cells[0, 4] := 'Maximum size of paging file';
  StringGrid1.Cells[0, 5] := 'Available in paging file';
  StringGrid1.Cells[0, 6] := 'Paging file load';
  StringGrid1.Cells[0, 7] := 'Virtual address space';
  StringGrid1.Cells[0, 8] := 'Free in address space';
  StringGrid1.Cells[0, 9] := 'Used address space';

  StringGrid2.Cells[0, 0] := 'Available address space ';
  StringGrid2.Cells[0, 1] := 'Uncommitted portion';
  StringGrid2.Cells[0, 2] := 'Committed portion';
  StringGrid2.Cells[0, 3] := 'Free portion';
  StringGrid2.Cells[0, 4] := 'Allocated portion';
  StringGrid2.Cells[0, 5] := 'Address space load';
  StringGrid2.Cells[0, 6] := 'Total small free blocks';
  StringGrid2.Cells[0, 7] := 'Total big free blocks';
  StringGrid2.Cells[0, 8] := 'Other unused blocks';
  StringGrid2.Cells[0, 9] := 'Total overhead';

  UpdateStatus;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  UpdateStatus;
end;

procedure TForm1.BtnStringClick(Sender: TObject);
begin
  // 10 megabytes
  SetLength(s, 10000000);
  UpdateStatus;
end;

procedure TForm1.BtnStringListClick(Sender: TObject);
var
  I: Integer;
begin
  sl := TStringList.Create;
  // add one thousand strings
  for I := 0 to 1000 do
    sl.Add('hello');
  // destroy some of them
  for I := 300 downto 1 do
    sl.Delete(I * 3);
  UpdateStatus;
end;

procedure TForm1.BtnFormClick(Sender: TObject);
var
  I: Integer;
begin
  // create ten forms
  for I := 1 to 10 do
    F := TForm.Create(Application);
  UpdateStatus;
end;

procedure TForm1.BtnSmallAllocClick(Sender: TObject);
var
  P: Pointer;
begin
  GetMem(P, 100);
  Integer(P^) := 10;
  UpdateStatus;
end;

procedure TForm1.BtnBigAllocClick(Sender: TObject);
var
  P: Pointer;
begin
  GetMem(P, 100000);
  Integer(P^) := 10;
  UpdateStatus;
end;

end.

Программное приложение на языке Delphi, предназначенное для мониторинга и тестирования использования памяти в системе Windows.

Основная форма (TForm1) содержит несколько кнопок, которые триггерят различные действия, связанные с аллокацией и деаллокацией памяти. Есть также два строковых грида (StringGrid1 и StringGrid2), которые отображают информацию о использовании памяти.

Вот подробное описание кода:

Создание формы Процедура FormCreate вызывается при создании основной формы. Она настраивает заголовки строкового грида и инициализирует некоторые переменные.

Обновление статуса памяти Процедура UpdateStatus вызывается для обновления строковых гридов с текущими статистиками памяти, такими как физическая нагрузка памяти, доступный адресный пространство и зарезервированная/аллокированная память. Она использует функцию GlobalMemoryStatus для получения статистики памяти и функцию GetHeapStatus для получения статистики кучи.

Процедуры кликов кнопок Каждая процедура клика кнопки триггерит конкретное действие:

• BtnStringClick: Аллоцирует 10 мегабайт памяти, установив длину строки (s) в 10000000.
• BtnStringListClick: Создает объект TStringList и добавляет/удаляет строки для тестирования использования памяти.
• BtnFormClick: Создает 10 форм для тестирования использования памяти.
• BtnSmallAllocClick и BtnBigAllocClick: Аллоцирует маленькие (100 байт) и большие (100000 байт) блоки памяти с помощью функции GetMem.

Замечания 1. Код использует встроенные функции Delphi для управления памятью, такие как GlobalMemoryStatus, GetHeapStatus и GetMem. 2. Процедура UpdateStatus вызывается периодически таймером (Timer1) для обновления статистики памяти, отображаемой в строковых гридах. 3. Приложение не обрабатывает ошибки или исключения, которые могут возникнуть при аллокации и деаллокации памяти.

В целом, это простое приложение для тестирования и мониторинга использования памяти в приложении Delphi. Однако оно может не быть подходящим для производства из-за своей простоты и отсутствия обработки ошибок.

Описание статьи 'Расширенные сведения о памяти' - статья, в которой автор представляет программу для отображения информации о состоянии памяти компьютера, включая физическую и страницированную память.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Память и Указатели ::