Вывести все зарегистрированные библиотеки типов

Delphi , Технологии , Технологии

Оформил: DeeCo
Автор: http://www.swissdelphicenter.ch

 uses
   Registry;

 procedure EnumTypeLibs(TypeLibNames: TStrings);
 var
   f: TRegistry;
   keyNames, keyVersions, keyInfos: TStringList;
   keyName, keyVersion, keyInfo, tlName: string;
   i, j, k: Integer;
 begin
   TypeLibNames.Clear;
   keyNames := nil;
   keyVersions := nil;
   keyInfos := nil;
   f := TRegistry.Create;
   try
     keyNames := TStringList.Create;
     keyVersions := TStringList.Create;
     keyInfos := TStringList.Create;
     f.RootKey := HKEY_CLASSES_ROOT;
     if not f.OpenKey('TypeLib', False) then raise
       Exception.Create('TRegistry.Open');
     f.GetKeyNames(keyNames);
     f.CloseKey;
     for i := 0 to keyNames.Count - 1 do
     begin
       keyName := keyNames.Strings[i];
       if not f.OpenKey(Format('TypeLib\%s', [keyName]), False) then Continue;
       f.GetKeyNames(keyVersions);
       f.CloseKey;
       for j := 0 to keyVersions.Count - 1 do
       begin
         keyVersion := keyVersions.Strings[j];
         if not f.OpenKey(Format('TypeLib\%s\%s', [keyName, keyVersion]), False) then
           Continue;
         tlName := f.ReadString('');
         f.GetKeyNames(keyInfos);
         f.CloseKey;
         {$B-}
         for k := 0 to keyInfos.Count - 1 do
         begin
           keyInfo := keyInfos.Strings[k];
           if (keyInfo = '') or (keyInfo[1] < '0') or (keyInfo[1] > '9') then Continue;
           if not f.OpenKey(Format('TypeLib\%s\%s\%s\win32', [keyName, keyVersion,
             keyInfo]), False) then Continue;
           f.CloseKey;
           TypeLibNames.Add(Format('%s ver.%s', [tlName, keyVersion]));
         end;
        {$B+}
       end;
     end;
   finally
     f.Free;
     keyNames.Free;
     keyVersions.Free;
     keyInfos.Free;
   end;
 end;

 // Example Call: 

procedure TForm1.Button1Click(Sender: TObject);
 begin
   EnumTypeLibs(ListBox1.Items);
 end;

Программа на Delphi, которая использует реестр Windows для перечисления и отображения всех зарегистрированных библиотек типов (TLBs) на системе.

Вот разбивка того, что код делает:

1. Процедура EnumTypeLibs принимает параметр TStrings, который будет использоваться для хранения списка имен библиотек типов.
2. Она создает объект TRegistry и устанавливает корневой ключ в HKEY_CLASSES_ROOT, где типовые библиотеки обычно зарегистрированы.
3. Она открывает подключение "TypeLib" и получает список имен ключей, которые представляют собой идентификаторы типовых библиотек (TLIDs).
4. Для каждого TLID она открывает соответствующее подключение, получает список версий и затем перебирает эти версии, чтобы найти те, которые имеют валидное подключение "win32".
5. В этом подключении "win32" она читает имя библиотеки типов из значения реестра с пустым именем (т.е., без конкретного значения).
6. Она добавляет каждое имя библиотеки типов и номер версии в параметр TStrings.

Пример кода в процедуре Button1Click демонстрирует, как вызывать эту процедуру и заполнять список библиотек типов в списке (ListBox1).

Некоторые предложения по улучшению:

• Рассмотрите добавление обработки ошибок для случаев, когда операции с реестром неудачны.
• Вам может понравиться отсортировать имена библиотек типов алфавитно или по номеру версии перед отображением их в списке.
• Если вы планируете использовать этот код в более крупной приложении, рассмотрите упаковку его в отдельный модуль для улучшения модулярности и повторного использования.

В отношении альтернативного решения, если вам нужно перечислить типовые библиотеки более современным способом, вы можете рассмотреть использование COM-интеропа или класса TypeLibHelper в .NET вместо реестра Windows. Однако, это код должен работать нормально и в контексте Delphi.

В статье описывается процедура EnumTypeLibs, которая выводит все зарегистрированные библиотеки типов в системе Windows.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Технологии ::