Отслеживание из DLL ее присоединение к процессу и отсоединение

Delphi , Файловая система , DLL и PlugIns

Автор: Xavier Pacheco

library DLLEntryLib;
uses
  SysUtils,
  Windows,
  Dialogs,
  Classes;

procedure DLLEntryPoint(dwReason: DWord);
begin
  case dwReason of
    DLL_PROCESS_ATTACH: ShowMessage('Attaching to process');
    DLL_PROCESS_DETACH: ShowMessage('Detaching from process');
    DLL_THREAD_ATTACH: MessageBeep(0);
    DLL_THREAD_DETACH: MessageBeep(0);
  end;
end;

begin
  { First, assign the procedure to the DLLProc variable }
  DllProc := @DLLEntryPoint;
  { Now invoke the procedure to reflect that the DLL is attaching to the
    process }
  DLLEntryPoint(DLL_PROCESS_ATTACH);
end.

{
Copyright © 1999 by Delphi 5 Developer's Guide - Xavier Pacheco and Steve Teixeira
}

unit MainFrm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls,
  Forms, Dialogs, StdCtrls, ComCtrls, Gauges;

type

  { Define a TThread descendant }
  TTestThread = class(TThread)
    procedure Execute; override;
    procedure SetCaptionData;
  end;

  TMainForm = class(TForm)
    btnLoadLib: TButton;
    btnFreeLib: TButton;
    btnCreateThread: TButton;
    btnFreeThread: TButton;
    lblCount: TLabel;
    procedure btnLoadLibClick(Sender: TObject);
    procedure btnFreeLibClick(Sender: TObject);
    procedure btnCreateThreadClick(Sender: TObject);
    procedure btnFreeThreadClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    LibHandle: THandle;
    TestThread: TTestThread;
    Counter: Integer;
    GoThread: Boolean;
  end;

var
  MainForm: TMainForm;

implementation

{$R *.DFM}

procedure TTestThread.Execute;
begin
  while MainForm.GoThread do
  begin
    Synchronize(SetCaptionData);
    Inc(MainForm.Counter);
  end;
end;

procedure TTestThread.SetCaptionData;
begin
  MainForm.lblCount.Caption := IntToStr(MainForm.Counter);
end;

procedure TMainForm.btnLoadLibClick(Sender: TObject);
{ This procedure loads the library DllEntryLib.DLL }
begin
  if LibHandle = 0 then
  begin
    LibHandle := LoadLibrary('DLLENTRYLIB.DLL');
    if LibHandle = 0 then
      raise Exception.Create('Unable to Load DLL');
  end
  else
    MessageDlg('Library already loaded', mtWarning, [mbok], 0);
end;

procedure TMainForm.btnFreeLibClick(Sender: TObject);
{ This procedure frees the library }
begin
  if not (LibHandle = 0) then
  begin
    FreeLibrary(LibHandle);
    LibHandle := 0;
  end;
end;

procedure TMainForm.btnCreateThreadClick(Sender: TObject);
{ This procedure creates the TThread instance. If the DLL is loaded a
  message beep will occur. }
begin
  if TestThread = nil then
  begin
    GoThread := True;
    TestThread := TTestThread.Create(False);
  end;
end;

procedure TMainForm.btnFreeThreadClick(Sender: TObject);
{ In freeing the TThread a message beep will occur if the DLL is loaded. }
begin
  if not (TestThread = nil) then
  begin
    GoThread := False;
    TestThread.Free;
    TestThread := nil;
    Counter := 0;
  end;

end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  LibHandle := 0;
  TestThread := nil;
end;

end.

Это проект на языке Delphi, который демонстрирует привязку и отключение DLL (динамической связанной библиотеки) к/от процесса, а также создание и остановка потока.

Вот разбивка кода:

Входная точка DLL DLL-элемент входной точки определена в модуле DLLEntryLib. Он содержит процедуру DLLEntryPoint, которая обрабатывает следующие события:

• DLL_PROCESS_ATTACH: Вызывается, когда DLL привязывается к процессу.
• DLL_PROCESS_DETACH: Вызывается, когда DLL отключается от процесса.
• DLL_THREAD_ATTACH: Вызывается, когда в процессе создается поток.
• DLL_THREAD_DETACH: Вызывается, когда поток завершается.

Процедура просто отображает сообщения с помощью функции ShowMessage и играет звуковые сигналы с помощью функции MessageBeep, чтобы указать события.

Основная форма Основная форма (TMainForm) содержит несколько кнопок, которые взаимодействуют с DLL:

• btnLoadLib: Загружает DLL.
• btnFreeLib: Освобождает DLL.
• btnCreateThread: Создает новый поток, который инкрементирует счетчик и обновляет метку на форме.
• btnFreeThread: Останавливает поток.

Основная форма также содержит целочисленную переменную Counter для отслеживания прогресса потока и булевую переменную GoThread для контроля создания и остановки потока.

Класс потока Класс TTestThread является наследником класса TThread. Он переопределяет метод Execute, который выполняется в отдельном потоке, и определяет процедуру SetCaptionData для обновления метки на форме.

Когда кнопка btnCreateThread нажата, создается новый экземпляр класса TTestThread и присваивается переменной TestThread. Переменная GoThread устанавливается в True, что позволяет потоку запуститься.

Когда кнопка btnFreeThread нажата, переменная GoThread устанавливается в False, что вызывает остановку потока.

Создание формы Событийный обработчик создания формы инициализирует handle DLL и экземпляр потока в nil.

В целом, это проект демонстрирует, как DLL может взаимодействовать с процессом и потоками в Delphi.

Отслеживание из DLL ее присоединение к процессу и отсоединение реализуется с помощью процедуры DLEntryPoint, которая вызывается при изменении состояния процесса или нити.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: DLL и PlugIns ::