Узнать версию драйвера принтера 2

Delphi , ОС и Железо , Принтеры и Печать

Оформил: DeeCo
Автор: http://www.swissdelphicenter.ch

 { Another Code by P. Below }

 unit Unit1;

 interface

 uses
   Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
   StdCtrls, WinSpool;

 type
   TForm1 = class(TForm)
     Button1: TButton;
     ListBox1: TListBox;
     Memo1: TMemo;
     procedure Button1Click(Sender: TObject);
     procedure FormDestroy(Sender: TObject);
     procedure ListBox1Click(Sender: TObject);
   private
     { Private-Deklarationen }
     pEnumDriversData: PDriverInfo2;

   public
     { Public-Deklarationen }
   end;

 var
   Form1: TForm1;

 implementation

 {$R *.DFM}

 procedure TForm1.ListBox1Click(Sender: TObject);
 var
   pTemp: PDriverInfo2;
 begin
   with Sender as TListbox do
    begin
     if ItemIndex >= 0 then
      begin
       memo1.Clear;
       pTemp := PDriverInfo2(Items.Objects[ItemIndex]);
       with memo1.Lines, pTemp^ do
        begin
         Add(Format('cVersion:'#9#9'%d'  , [cVersion]));
         Add(Format('pName:'#9#9'%s'  , [pName]));
         Add(Format('pEnvironment:'#9'%s'  , [pEnvironment]));
         Add(Format('pDriverPath:'#9'%s'  , [pDriverPath]));
         Add(Format('pDataFile:'#9#9'%s'  , [pDataFile]));
         Add(Format('pConfigFile:'#9'%s'  , [pConfigFile]));
       end;
     end;
   end;
 end;

 procedure TForm1.Button1Click(Sender: TObject);
 var
   i, bytesNeeded: DWORD;
   pTemp: PDriverInfo2;
   NumDrivers: DWORD;
 begin
   listbox1.Clear;
   if Assigned(pEnumDriversData) then
     FreeMem(pEnumDriversData);
   // get number of installed drivers 
  Numdrivers := 0;
   bytesNeeded := 0;
   EnumPrinterDrivers(nil, nil, 2, nil, 0, bytesNeeded, NumDrivers);
   if bytesNeeded = 0 then
    begin
     ShowMessage('No printer drivers installed!');
     Exit;
   end;

   // allocate memory for the driver data 
  GetMem(pEnumDriversData, bytesNeeded);
   // fetch driver data 
  if EnumPrinterDrivers(nil, nil, 2, pEnumDriversData, bytesNeeded,
     bytesNeeded, NumDrivers) then
    begin
     // add drivers to listbox1 
    pTemp := pEnumDriversData;
     for i := 1 to Numdrivers do
      begin
       listbox1.Items.AddObject(pTemp^.pName, TObject(pTemp));
       Inc(pTemp);
       // Note: Inc increments a pointer by the size of its base type! 
    end;
     listbox1.ItemIndex := 0;
     listbox1Click(listbox1);
   end
   else
     RaiseLastWin32Error;
 end;

 procedure TForm1.FormDestroy(Sender: TObject);
 begin
   if Assigned(pEnumDriversData) then
     FreeMem(pEnumDriversData);
 end;

 end.

Программа на Delphi, которая перечисляет установленные на системе драйверы принтеров и отображает информацию о версии в списке.

Вот разбивка кода:

1. Программа определяет форму (TForm1) с тремя компонентами: Button1, ListBox1 и Memo1. Кнопка Button1 запускает перечисление драйверов, список ListBox1 отображает список драйверов, а текстовый блок Memo1 отображает подробную информацию о каждом драйвере.
2. В обработчике события клика кнопки Button1 программа вызывает функцию EnumPrinterDrivers, чтобы перечислить установленные на системе драйверы принтеров. Затем она выделяет память для данных драйвера с помощью GetMem.
3. Программа итерирует по списку драйверов и добавляет имя каждого драйвера в список ListBox1. Для каждого элемента также хранит указатель на структуру данных драйвера (PDriverInfo2) в объекте Items.
4. Когда пользователь выбирает элемент в списке ListBox1, обработчик события клика списка получает соответствующие данные драйвера и отображает информацию о версии в текстовом блоке Memo1. Информация о версии хранится в поле cVersion структуры PDriverInfo2.
5. В обработчике события уничтожения формы программа освобождает выделившуюся память для данных драйвера с помощью FreeMem.

Чтобы определить версию конкретного драйвера принтера, пользователь может выбрать драйвер в списке и просмотреть информацию о версии, отображенную в текстовом блоке Memo1. Информация о версии хранится в поле cVersion структуры PDriverInfo2.

Обратите внимание, что эта программа требует включения единицы WinSpool, которая предоставляет функцию EnumPrinterDrivers.

В статье описывается код на языке Delphi, который позволяет узнать версию драйвера принтера и другие параметры его работы.

Комментарии и вопросы

Получайте свежие новости и обновления по Object Pascal, Delphi и Lazarus прямо в свой смартфон. Подпишитесь на наш Telegram-канал delphi_kansoftware и будьте в курсе последних тенденций в разработке под Linux, Windows, Android и iOS

:: Главная :: Принтеры и Печать ::